Embedded browser

Marco Lohnen · May 29, 2008, 05:49:24 AM

Hi all,

I'd like to use the embedded browser control without showing scrollbars.. any ideas? Have to use it for some kind of narrowcasting display software..

Marco

LarryMc · May 29, 2008, 06:11:18 AM

As far as I know that is a totally HTML page issue.

On my genealogy website I do it using FRAMES.

See http://www.faqs.org/docs/htmltut/frames/_FRAME_SCROLLING.html for some info.

Larry

Marco Lohnen · May 29, 2008, 06:21:05 AM

Thanks Larry, but this seems to be in the control itself.
I get a scrollbar as soon as I use the control, even if it is an empty HTML page..
In VB6 I was able to get it done by using the 'Theatermode'

Marco

LarryMc · May 29, 2008, 07:03:16 AM

Quote from: Marco Lohnen on May 29, 2008, 06:21:05 AM

I get a scrollbar as soon as I use the control, even if it is an empty HTML page..

Which is the default. Frames has the command to override the scrollbars.

Attached is a eba file that opens a main window and then a child window with an attached browser.

The default page is loaded (index.htm) which contains the frameset info plus it loads the html file noscroll.htm which shows the text and the browser window has no scrollbars.

There might be an easier way to do it but I know this stripped down frameset works.

Larry

sapero · May 29, 2008, 09:42:23 AM

Marco, use one of

Code Select

<body scroll="no">
<body style="overflow:hidden">

More reading and links at http://forum.echoechoplus.com/showthread.php?threadid=8498

LarryMc · May 29, 2008, 10:14:21 AM

whether my way or sapero's way it is still a function of the content of the html page.

Quote<body scroll="no">

I read that that is only recognized by IE browsers but since the EBasic browser is based upon an IE browser it should be no problem.

Larry

sapero · May 29, 2008, 10:32:12 AM

Yet another possiblity is to set the 'scroll' property at runtime:

Code Select

$include "exdisp.inc"
$include "mshtml.inc"

WINDOW win
OPENWINDOW win,0,0,800,600,@NOAUTODRAW|@SIZE|@MINBOX|@MAXBOX,0,"BROWSER TEST",&handler


WAITUNTIL win.hwnd=0


SUB handler
	SELECT @MESSAGE

		CASE @IDCREATE
			ATTACHBROWSER *<WINDOW>@HITWINDOW
			BROWSECMD *<WINDOW>@HITWINDOW, @GOHOME

		CASE @IDCLOSEWINDOW
			CloseWindow *<WINDOW>@HITWINDOW

		CASE @IDNAVCOMPLETE
			RemoveBrowserScrollbars(*<WINDOW>@HITWINDOW)

	ENDSELECT
	RETURN
ENDSUB



SUB RemoveBrowserScrollbars(WINDOW win)
	' attached browser MUST be navigated
	'
	pointer p
	IUnknown         unk
	IWebBrowser2     browser
	IDispatch        disp
	IHTMLDocument2   document
	IHTMLElement     bodyelement
	IHTMLBodyElement body
	BSTR             bstrNo

	p = GetProp(win.hwnd, "BROWSER")
	if (p)
		unk = *<comref>p
		' browser->document.body.scroll="false"
		unk->QueryInterface(_IID_IWebBrowser2, &browser)

		browser->get_Document(&disp)
		browser->Release()

		disp->QueryInterface(_IID_IHTMLDocument2, &document)
		disp->Release()

		document->get_body(&bodyelement)
		document->Release()

		bodyelement->QueryInterface(_IID_IHTMLBodyElement, &body)
		bodyelement->Release()

		bstrNo = SysAllocString(L"no")
		body->put_scroll(bstrNo)
		body->Release()
		SysFreeString(bstrNo)
	endif

	RETURN
ENDSUB

LarryMc · May 29, 2008, 10:49:27 AM

Sapero,

I was just about to tell him that.........NOT!!!!

It amazes me with how you come up with all that stuff.

Larry

Marco Lohnen · May 30, 2008, 12:18:32 AM

Fantastic Guys!

Thanks both for your help..

Marco

IonicWind Software

News:

Embedded browser

Marco Lohnen

May 29, 2008, 05:49:24 AM

LarryMc

May 29, 2008, 06:11:18 AM #1

Marco Lohnen

May 29, 2008, 06:21:05 AM #2

LarryMc

May 29, 2008, 07:03:16 AM #3

sapero

May 29, 2008, 09:42:23 AM #4

LarryMc

May 29, 2008, 10:14:21 AM #5

sapero

May 29, 2008, 10:32:12 AM #6

LarryMc

May 29, 2008, 10:49:27 AM #7

Marco Lohnen

May 30, 2008, 12:18:32 AM #8